townforge/GameData/Shaders/GLSL/TownforgeTerrain.glsl

#include "Uniforms.glsl"
#include "Samplers.glsl"
#include "Transform.glsl"
#include "ScreenPos.glsl"
#include "Lighting.glsl"
#include "Fog.glsl"

varying vec2 vTexCoord;

#ifndef GL_ES
varying vec2 vDetailTexCoord;
#else
varying mediump vec2 vDetailTexCoord;
#endif

varying vec3 vNormal;
varying vec4 vWorldPos;
#ifdef PERPIXEL
    #ifdef SHADOW
        #ifndef GL_ES
            varying vec4 vShadowPos[NUMCASCADES];
        #else
            varying highp vec4 vShadowPos[NUMCASCADES];
        #endif
    #endif
    #ifdef SPOTLIGHT
        varying vec4 vSpotPos;
    #endif
    #ifdef POINTLIGHT
        varying vec3 vCubeMaskVec;
    #endif
#else
    varying vec3 vVertexLight;
    varying vec4 vScreenPos;
    #ifdef ENVCUBEMAP
        varying vec3 vReflectionVec;
    #endif
    #if defined(LIGHTMAP) || defined(AO)
        varying vec2 vTexCoord2;
    #endif
#endif

uniform sampler2D sWeightMap0;
uniform sampler2D sDetailMap1;
uniform sampler2D sDetailMap2;
uniform sampler2D sDetailMap3;
uniform sampler2D sDetailMap4;
uniform sampler2D sDetailMap5;
uniform sampler2D sHighlightMap6;
#ifdef SNOWTEXTURE
uniform sampler2D sSnowMap7;
#endif
uniform sampler2D sSurfMap8;
uniform sampler2D sNoiseMap9;

#ifndef GL_ES
uniform vec2 cDetailTiling;
#else
uniform mediump vec2 cDetailTiling;
#endif

#ifdef SNOWTEXTURE
uniform float cTemperature;
uniform float cSnowinessMinTemperature;
uniform float cSnowinessMaxTemperature;
uniform float cTemperatureAltitudeFloor;
uniform float cTemperatureAltitudeDecrease;
uniform float cMaxSnowDepth;

const float min_snow_threshold = 0.25;
const float max_snow_threshold = 0.95;
const float snow_saturation = 0.15;
uniform float cSnowDarkening;
#ifndef SNOWTEXTURE
const vec4 snowColor = vec4(184.0 / 255.0, 183.0 / 255.0, 209 / 255.0, 1.0);
#endif

#endif

uniform vec4 cHighlightColor;
uniform float cSandThreshold;

const float sand_rgb_multiplier = 0.6;
const float sand_tiling_multiplier = 4.0;

#ifdef WATER
uniform float cWaterLevel;
varying float water_depth;
#endif

#ifdef SNOWTEXTURE
varying float snowiness;
varying float snow_depth;

float GetSnowinessAtHeight(float height)
{
#ifdef WATER
  if (height < cWaterLevel)
    return 0.0;
#endif
  height = max(height - cTemperatureAltitudeFloor, 0.0);
  float temperature = cTemperature - height * cTemperatureAltitudeDecrease;
  temperature = max(temperature, cSnowinessMinTemperature);
  temperature = min(temperature, cSnowinessMaxTemperature);
  return (cSnowinessMaxTemperature - temperature) / (cSnowinessMaxTemperature - cSnowinessMinTemperature);
}
#endif

void VS()
{
    mat4 modelMatrix = iModelMatrix;
    vec3 worldPos = GetWorldPos(modelMatrix);
    gl_Position = GetClipPos(worldPos);
    vNormal = GetWorldNormal(modelMatrix);
    vWorldPos = vec4(worldPos, GetDepth(gl_Position));
    vTexCoord = GetTexCoord(iTexCoord);
    vDetailTexCoord = cDetailTiling * vTexCoord;

    #ifdef PERPIXEL
        // Per-pixel forward lighting
        vec4 projWorldPos = vec4(worldPos, 1.0);

        #ifdef SHADOW
            // Shadow projection: transform from world space to shadow space
            for (int i = 0; i < NUMCASCADES; i++)
                vShadowPos[i] = GetShadowPos(i, vNormal, projWorldPos);
        #endif

        #ifdef SPOTLIGHT
            // Spotlight projection: transform from world space to projector texture coordinates
            vSpotPos = projWorldPos * cLightMatrices[0];
        #endif
    
        #ifdef POINTLIGHT
            vCubeMaskVec = (worldPos - cLightPos.xyz) * mat3(cLightMatrices[0][0].xyz, cLightMatrices[0][1].xyz, cLightMatrices[0][2].xyz);
        #endif
    #else
        // Ambient & per-vertex lighting
        #if defined(LIGHTMAP) || defined(AO)
            // If using lightmap, disregard zone ambient light
            // If using AO, calculate ambient in the PS
            vVertexLight = vec3(0.0, 0.0, 0.0);
            vTexCoord2 = iTexCoord1;
        #else
            vVertexLight = GetAmbient(GetZonePos(worldPos));
        #endif
        
        #ifdef NUMVERTEXLIGHTS
            for (int i = 0; i < NUMVERTEXLIGHTS; ++i)
                vVertexLight += GetVertexLight(i, worldPos, vNormal) * cVertexLights[i * 3].rgb;
        #endif
        
        vScreenPos = GetScreenPos(gl_Position);

        #ifdef ENVCUBEMAP
            vReflectionVec = worldPos - cCameraPos;
        #endif
    #endif

    #ifdef SNOWTEXTURE
        snowiness = GetSnowinessAtHeight(vWorldPos.y);
        float snow_threshold = min_snow_threshold * snowiness + max_snow_threshold * (1.0 - snowiness);
        float upness = min((max(2.0 * snowiness * dot(vNormal, vec3(0.0, 1.0, 0.0)), snow_threshold) - snow_threshold) / (1.0 + snow_saturation - snow_threshold), 1.0);
        snow_depth = snowiness * max((upness - 0.5), 0.0) * 2;
    #endif
    // gl_Position.y += snow_depth * cMaxSnowDepth;

#ifdef WATER
    water_depth = vWorldPos.y - cWaterLevel;
#endif
}

#ifdef TEXTURE_NOTILE
// https://iquilezles.org/articles/texturerepetition/
float sumv( vec4 v ) { return v.x+v.y+v.z; }
vec4 textureNoTile( sampler2D s, in vec2 uv, in vec2 pos )
{
    // sample variation pattern
    float k = texture2D( sNoiseMap9, 0.001*pos ).x; // cheap (cache friendly) lookup

    // compute index
    float index = k*8.0;
    float i = floor( index );
    float f = fract( index );

    // offsets for the different virtual patterns
    vec2 offa = sin(vec2(3.0,7.0)*(i+0.0)); // can replace with any other hash
    vec2 offb = sin(vec2(3.0,7.0)*(i+1.0)); // can replace with any other hash

    // sample the two closest virtual patterns
    vec4 cola = texture2D( s, uv + offa);
    vec4 colb = texture2D( s, uv + offb);

    // interpolate between the two virtual patterns
    return mix( cola, colb, smoothstep(0.2,0.8,f-0.1*sumv(cola-colb)) );
}
#else
vec4 textureNoTile( sampler2D s, in vec2 uv, in vec2 pos )
{
    return texture2D(s, uv);
}
#endif

void PS()
{
    // Get material diffuse albedo
    vec4 diffColor;
    vec3 weights = texture2D(sWeightMap0, vTexCoord).rgb;
    float sumWeights = weights.r + weights.g + weights.b;
    if (sumWeights == 0.0)
    {
        diffColor = cMatDiffColor * (
#ifndef SNOWTEXTURE
          textureNoTile(sDetailMap5, vDetailTexCoord * sand_tiling_multiplier, vWorldPos.xz) * sand_rgb_multiplier
#else
          textureNoTile(sDetailMap5, vDetailTexCoord, vWorldPos.xz) * (1.0 - snowiness) +
          textureNoTile(sDetailMap4, vDetailTexCoord, vWorldPos.xz) * snowiness
#endif
      );
    }
    else
    {
      weights /= sumWeights;
      diffColor = cMatDiffColor * (
#ifndef SNOWTEXTURE
        weights.r * textureNoTile(sDetailMap1, vDetailTexCoord, vWorldPos.xz) +
#else
        weights.r * textureNoTile(sDetailMap1, vDetailTexCoord, vWorldPos.xz) * (1.0 - snowiness) +
        weights.r * textureNoTile(sDetailMap4, vDetailTexCoord, vWorldPos.xz) * snowiness +
#endif
        weights.g * textureNoTile(sDetailMap2, vDetailTexCoord, vWorldPos.xz) + 
        weights.b * textureNoTile(sDetailMap3, vDetailTexCoord, vWorldPos.xz)
      );
    }

    // Get material specular albedo
    vec3 specColor = cMatSpecColor.rgb;

    // Get normal
    #ifdef APPROXIMATENORMAL
    vec3 normal = vNormal;
    #else
    vec3 normal = normalize(vNormal);
    #endif

    #ifdef SNOWTEXTURE
        vec4 snowColor = textureNoTile(sSnowMap7, vTexCoord * 2, vWorldPos.xz) * cSnowDarkening;
        diffColor = diffColor * (1.0 - snow_depth) + snowColor * snow_depth * cSnowDarkening;
    #endif

    // Get fog factor
    #ifdef HEIGHTFOG
        float fogFactor = GetHeightFogFactor(vWorldPos.w, vWorldPos.y);
    #else
        float fogFactor = GetFogFactor(vWorldPos.w);
    #endif

    #if defined(PERPIXEL)
        // Per-pixel forward lighting
        vec3 lightColor;
        vec3 lightDir;
        vec3 finalColor;
        
        float diff = GetDiffuse(normal, vWorldPos.xyz, lightDir);

        #ifdef SHADOW
            diff *= GetShadow(vShadowPos, vWorldPos.w);
        #endif
    
        #if defined(SPOTLIGHT)
            lightColor = vSpotPos.w > 0.0 ? texture2DProj(sLightSpotMap, vSpotPos).rgb * cLightColor.rgb : vec3(0.0, 0.0, 0.0);
        #elif defined(CUBEMASK)
            lightColor = textureCube(sLightCubeMap, vCubeMaskVec).rgb * cLightColor.rgb;
        #else
            lightColor = cLightColor.rgb;
        #endif
    
        #ifdef SPECULAR
            float spec = GetSpecular(normal, cCameraPosPS - vWorldPos.xyz, lightDir, cMatSpecColor.a);
            finalColor = diff * lightColor * (diffColor.rgb + spec * specColor * cLightColor.a);
        #else
            finalColor = diff * lightColor * diffColor.rgb;
        #endif

        #ifdef AMBIENT
            finalColor += cAmbientColor.rgb * diffColor.rgb;
            finalColor += cMatEmissiveColor;
            gl_FragColor = vec4(GetFog(finalColor, fogFactor), diffColor.a);
        #else
            gl_FragColor = vec4(GetLitFog(finalColor, fogFactor), diffColor.a);
        #endif
    #elif defined(PREPASS)
        // Fill light pre-pass G-Buffer
        float specPower = cMatSpecColor.a / 255.0;

        gl_FragData[0] = vec4(normal * 0.5 + 0.5, specPower);
        gl_FragData[1] = vec4(EncodeDepth(vWorldPos.w), 0.0);
    #elif defined(DEFERRED)
        // Fill deferred G-buffer
        float specIntensity = specColor.g;
        float specPower = cMatSpecColor.a / 255.0;

        gl_FragData[0] = vec4(GetFog(vVertexLight * diffColor.rgb, fogFactor), 1.0);
        gl_FragData[1] = fogFactor * vec4(diffColor.rgb, specIntensity);
        gl_FragData[2] = vec4(normal * 0.5 + 0.5, specPower);
        gl_FragData[3] = vec4(EncodeDepth(vWorldPos.w), 0.0);
    #else
        // Ambient & per-vertex lighting
        vec3 finalColor = vVertexLight * diffColor.rgb;

        #ifdef MATERIAL
            // Add light pre-pass accumulation result
            // Lights are accumulated at half intensity. Bring back to full intensity now
            vec4 lightInput = 2.0 * texture2DProj(sLightBuffer, vScreenPos);
            vec3 lightSpecColor = lightInput.a * lightInput.rgb / max(GetIntensity(lightInput.rgb), 0.001);

            finalColor += lightInput.rgb * diffColor.rgb + lightSpecColor * specColor;
        #endif

        gl_FragColor = vec4(GetFog(finalColor, fogFactor), diffColor.a);
    #endif

    float selected = texture2D(sHighlightMap6, vTexCoord).r;
    gl_FragColor = gl_FragColor * (1.0 - selected / 2.0) + cHighlightColor * selected / 2.0;

#ifdef WATER
    if (water_depth < 0.0)
    {
        float t_green = max(1.0 + water_depth * 0.2, 0.0) * 0.35;
        gl_FragColor = mix(gl_FragColor, vec4(0.2, 1.0, 0.7, 1.0), t_green);
        float t_white = max(1.0 + water_depth * 2.0, 0.0);
        vec4 surf_dest = vec4(1.0, 1.0, 1.0, 1.0);
        gl_FragColor = mix(gl_FragColor, surf_dest, t_white);
    }
#endif
}